*  JieJie Microelectronics P-Spice Model Library
*  Filename	: JMSH1004AE_P v.20210618.txt
*  Product Name      	: JMSH1004AE (TO263-3L)
*  Configuration:	: Single N-channel Device
*  Data Sheet Rev.	: 2.0
*  Release Date	: June 3, 2021
*  Junction Temp (Tj)	: -40C ~ 150C
******************************************************************************************************
*  This model is designed as a tool to assist end user(s) to evaluate the performance
*  of the specific SGT MOSFET from JJMSH(R).  It has been verified for function and
*  timing integrity with the commercially available EDA simulation tools. End-user(s)
*  is/are advised to take the best engineering practice (e.g. bread-boarding, labora-
*  tory measurement for the full evaluation.
*
*  Despite of the best effort on engineering & verification, JieJie Microelectronics
*  ("JJM") does not provide any warranty nor take any liability to the results and their
*  effects whatsoever from the simulation run of this model by the end-user(s). While
*  this model may be updated at appropriate times in the future without prior notice,
*  JJM does not assume the sole responsibility for update. 
*
.subckt MSH1004AE D G S   
M1 1 2 3 3 NMOS L=1E-006 W=1E-006
Vmonitor D 18
RD 18 1 0.0009
RS S 3 1E-006
RG G 17 2.5
CGS 3 G 4.15E-9
EGD 12 0 2 1 1
Etemp 17 2 VALUE = {(-0.000346*(TEMP-25))+((-1.08647E-9)*(TEMP-25)^2)}
Gtemp 1 3 VALUE = {I(Vmonitor)*((TEMP+273)/(298)-((TEMP+273)/(298))^1.55)}
VFB 14 0 0
FFB 2 1 VFB 1
CGD 13 14 1.25E-9
DDG 15 14 DCGD
R2 12 15 1
D2 15 0 DLIM
DSD 3 D DSUB
RR 13 0 1
D1 12 13 DLIM
CDS D 3 Cbreak 4.05963E-9
.MODEL Cbreak CAP (C = 1 VC1 = -0.01768 VC2 = 9.00218E-5)
.model NMOS NMOS
+LEVEL = 3                                        
+VMAX = 1.0752E9               ETA = 1E-4                    
+VTO = 2.98156                 TOX = 8E-10                   NSUB = 3.55E15                
+KP = 315.44                   U0 = 424                      KAPPA = 5.856E-10             
+GAMMA = 1.59                  PHI = 0.515242                THETA = 0.490262              
+BEX = -2.2                    TCV = 4.5E-3                  DELTA = 57.8475 
.MODEL DCGD D
+CJO     = 7.36104e-10     VJ      = 3.555E1           M       = 2.755 
.model DSUB D
+IS = 4.10418E-10              N = 1.1466                    RS = 3.52688E-3               
+BV = 109                      xti = -0.06                   
.model DLIM D
+IS = 1E-4                    
.ends MSH1004AE

******************************************************************************************************
*  Copyright (C) 2021 JJM. All rights reserved.
******************************************************************************************************